사비가 그루잠 버서커 지역에서 사용하고 있는 tintin++용 자반입니다.

#config {command echo} off
#var ID {아이디}
#var PASS {암호}

#al {groozam} {#sess groozam groozam.net 4000}
#event {SESSION DISCONNECTED} {#gts #delay 5 groozam}
#ac {접속 : connect 아이디 패스워드} {con $ID $PASS}

#ac {^사비님이 들어왔습니다.} {모두착용;파티준비}

#nop =================================================================
#nop 메인
#nop =================================================================
#al {자동사냥시작} {#var auto 1;mapremove;mapset;st;#delay 1 봐;#ac {^'%%1' 명령은 사용할 수 없습니다.} {명령오류}}
#al {자동사냥종료} {#var auto 0;mapremove;#unac {갈 수 있는 곳은};#unac {^'%%1' 명령은 사용할 수 없습니다.}}

#al {1} {자동사냥시작;'버프;정보}
#al {0} {자동사냥종료}

#ac {전투가 끝났다} {이동판단}

#al {st} {#ac {갈 수 있는 곳은} {#math idx $idx+1;이동판단}}

#al {이동판단} {#if {$idx > $END} {#math {sum_mapcount} {$sum_mapcount + 1};'버프;#var idx 1;계속이동} {계속이동}}
#al {계속이동} {${MAP$idx}}

#nop 버서커 지역
#var path {deesssssswwwwsssssswwwwwwwsswwwwwwwwwnnnnnnnnnnnnnwwwwwwwwwwwwnnnnwwneeeeswwsssseenneeeeswwwweeeeeeeeeeeeeeeeswwwwwwwwwwwwwwwwseeeeeeeeeeeeeeeeswwwwwwwsesssssssssseeeeeeeeeeenneeeeennnnnnnneeeennnnwwu}

#al {mapset} {#var idx 0;#parse {$path} {char} {#math idx {$idx+1};#var MAP${idx} $char};#var END $idx;#var idx 0}
#al {mapremove} {#unvar idx;#loop 1 $END loop {#unvar MAP{$loop}};#unvar END}

#al {e} {동}
#al {w} {서}
#al {s} {남}
#al {n} {북}
#al {u} {위}
#al {d} {아래}

#nop =================================================================
#nop 예외처리
#nop =================================================================
#al {명령오류} {#if {$auto == 1} {자동사냥종료;#delay 1 {사용 묵약의탑귀환주문서};#delay 5 자동사냥시작}}
#ac {^ ... 서버가 재가동되었습니다.} {자동사냥종료;#delay 1 모두착용;#delay 2 파티준비;#delay 3 {사용 묵약의탑귀환주문서};#delay 7 자동사냥시작}

#nop =================================================================
#nop 전투
#nop =================================================================
#ac {^[%1/%2, %3/%4]} {#var hp %1;#var maxhp %2;#var fp %3;#var maxfp %4}
#ac {! [%1/%2]} {#var hp %1;#var maxhp %2;공격스킬;치료}

#al {공격스킬} {#if {$hp < ($maxhp * 0.9)} {#if {$fp >= 3} 절단}}

#al {치료} {#if {$hp < ($maxhp * 0.5)} {힐;'전사공격}}
#var heal 1
#al {힐} {#if {$heal == 1} {'힐1;#math {heal} {$heal * (-1)}} {'힐2;#math {heal} {$heal * (-1)}}}

#ac {%1, %2이 있다} {'전사공격}
#ac {%1, %2가 있다} {'전사공격}
#ac {%1, %2, %3이 있다} {'모두공격}
#ac {%1, %2, %3가 있다} {'모두공격}
#ac {%1, %2, %3, %4이 있다} {'모두공격}
#ac {%1, %2, %3, %4가 있다} {'모두공격}
#ac {%1이 풀렸습니다.} {'버프 %1}
#ac {%1가 풀렸습니다.} {'버프 %1}

#nop =================================================================
#nop 사냥 정보
#nop =================================================================
#al {정보} {정보꺼;#ac {^-[[ } {시간계산;#showme <acf>자동사냥: $idx/$END, 반복: $sum_mapcount, 사냥: $sum_mobcount 마리, 경험치: $sum_exp, 시간: $time 분}}
#al {정보꺼} {#unac {^-[[ };#var sum_mapcount 0;#var sum_mobcount 0;#var sum_exp 0;#var sum_money 0;#format {start} {%T}}
#var sum_mapcount 0
#var sum_mobcount 0
#var sum_exp 0
#var sum_money 0
#var time 0
#al {시간계산} {#format {now} {%T};#math {time} {(($now - $start)/60)}}
#ac {^경험치 %1점을 획득했습니다.} {#math {sum_exp} {$sum_exp + %1}}
#ac {^경험치 %1점을 잃었습니다.} {#math {sum_exp} {$sum_exp - %1}}
#ac {^%1브론즈를 획득했습니다.} {#math {sum_momey} {$sum_money + %1}}
#ac {^듀라한이 쓰러졌다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}
#ac {^버서커가 쓰러졌다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}
#ac {^스켈레톤 워리어가 쓰러졌다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}
#ac {^스켈레톤 아쳐가 쓰러졌다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}
#ac {^거대한 좀비가 쓰러졌다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}
#ac {^난폭한 스켈레톤 뼈가 산산조각 났다... 죽었다.} {#math {sum_mobcount} {$sum_mobcount + 1}}

#nop =================================================================
#nop 파티
#nop =================================================================
#al {파티준비} {파티만들기;파티초청 트리;파티초청 마법사;파티초청 틴틴;파티초청 제제}
#ac {^트리님이 들어왔습니다.} {파티초청 트리}
#ac {^마법사님이 들어왔습니다.} {파티초청 마법사}
#ac {^틴틴님이 들어왔습니다.} {파티초청 틴틴}
#ac {^제제님이 들어왔습니다.} {파티초청 제제}

#nop =================================================================
#nop 아이템 정리
#nop =================================================================
#ac {^나이프를 획득} {던져}
#ac {^대거를 획득} {버려 1대거}
#ac {^롱소드를 획득} {버려 1롱소드}
#ac {^매직스태프를 획득} {버려 1매직스태프}
#ac {^클럽을 획득} {버려 1클럽}
#ac {^액스를 획득} {버려 1액스}
#ac {^레더%1 획득} {버려 1레더}
#ac {^스케일%1 획득} {버려 1스케일}
#ac {^플레이트%1 획득} {버려 1플레이트}
#ac {^브로드소드를 획득} {버려 1브로드소드}
#ac {^워해머를 획득} {버려 1워해머}
#ac {^룬액스를 획득} {버려 1룬액스}
#ac {^세이지스태프를 획득} {버려 1세이지스태프}
#ac {^세이지로브를 획득} {버려 1세이지로브}
#ac {^롱보우를 획득} {버려 1롱보우}
#ac {^크로스보우를 획득} {버려 1크로스보우}
#ac {^스켈레톤%1 획득} {버려 1스켈레톤}

#ac {^가죽을 획득} {소각 가죽}
#ac {^나무를 획득} {소각 나무}
#ac {^뼈를 획득} {소각 뼈}